/*
 * BarChartSimple.fx
 *
 * Created on 05/02/2010, 3:54:17 PM
 */
package org.outrospective.charts.demo;

import javafx.stage.Stage;
import javafx.scene.Scene;
import javafx.scene.text.Text;
import javafx.scene.text.Font;
import javafx.scene.chart.BarChart;
import javafx.scene.chart.part.CategoryAxis;
import javafx.scene.chart.part.NumberAxis;
import javafx.scene.input.MouseEvent;
import java.util.Random;

/**
 * @author Kon
 */
def barChartRef = [
            BarChart.Data {category: "Child", value: 10},
            BarChart.Data {category: "Refined", value: 80},
            BarChart.Data {category: "Peaking", value: 25},
            BarChart.Data {category: "Middle-Aged", value: 40}
            BarChart.Data {category: "Grand-parenting", value: 60}
            BarChart.Data {category: "Teen", value: 16}
        ];

var categories = ["Child", "Teen", "Peaking", "Middle-Aged", "Grand-parenting", "Refined"];
var barChartData: BarChart.Data[];

Stage {
    title: "Live BarChart Demo"
    scene: Scene {
        width: 800
        height: 600
        content: [
            Text {
                font: Font {
                    size: 16
                }
                x: 10
                y: 30
                content: "Demo"
            },
            BarChart {
                categoryAxis: CategoryAxis {
                    categories: bind categories
                }
                valueAxis: NumberAxis {
                    lowerBound: 0
                    upperBound: 80
                    tickUnit: 10
                    label: "Age"
                }
                translateX: 10
                translateY: 50
                title: "Bar Chart"
                data: [BarChart.Series {
                        name: "Click Here to add bars to the chart",
                        data: bind barChartData}
                ]
                onMouseClicked: function (e: MouseEvent): Void {
                    def nextElement = barChartData.size();
                    println ("Inserting ref element {nextElement}");
                    if (nextElement < 6)
                        insert barChartRef[nextElement] into barChartData
                    else {
                        insert "Category {nextElement}" into categories;
                        insert BarChart.Data {value:new Random().nextInt(81)} into barChartData;
                    }
                }
            }
        ]
    }
}